Rully Yulian MF

Bandung MSDN Day (29 Nov 08) Event Report

yulian — Sun, 30 Nov 2008 14:19:00 GMT

Hari Sabtu pada tanggal 29 Nov 2008 telah diadakan event MSDN Day di Bandung. Menurut saya yang selama ini tinggal di Bandung, event tersebut merupakan event terbesar di Bandung yang pernah diadakan oleh Microsoft. Peserta yang hadir sekitar kurang lebih 1000 orang yang notabene merupakan mahasiswa. Memang selama ini MUGI Bandung membantu mempromosikan event ini kebanyakan ke kampus-kampus yang ada di Bandung, baik itu swasta maupun Negeri. Begitu juga mungkin dengan HMIF ITB.

Pada event ini untuk materi dibagi kedalam 2 track, yaitu IT Pro dan Developer. Semua peserta tampak antusias dan sabar menunggu sampai event tersebut berakhir :) . MUGI Bandung membuka stand disana untuk pendaftaran anggota baru yang ingin bergabung. Para pendaftar cukup mengisi nama, email, asal institusi. Selain itu kita bagi-bagi stiker MUGI Bandung yang habis sebanyak 150 lembar. Jumlah pendaftar juga cukup lumayan yaitu sekitar 150 orang lebih, yang akan kita invite nantinya ke milis MUGI Bandung. Selain itu juga di stand pendaftaran kita sempat bagi-bagi cd-cd video training, dan buku-buku lewat game quiz pertanyaan.

Dibawah ini foto-foto yang saya ambil dari kamera-kamera yang jepret-jepret waktu itu :D...bagi speaker yang ga ada fotonya dibawah ini maaf ya soalnya foto-foto ini juga comotan dari sana sini :))...yang punya account di facebook silahkan dilihat-lihat disana :D

Peserta :

Speakers :

Duet bareng Reza :)

Sambil jualan, promosi, sempet-sempetnya juga difoto anak-anak MUGI Bandung ini :))

Bisa-bisanya difoto pas lagi ada presentasi :))

Mbak Evi laku tuh disana dimintain foto-foto, cape ya mbak ;)) (Btw posisi tangan kanannya reza agak aneh tuh (curiga) :)) )

Wah ini nih, pak Firstman...ntar ketauan nyoya loh :)) Luki juga tuh ;))

Foto bareng setelah acara selesai :

Makan-makan bareng @ d'Palm abis acara selesai dan beres-beres :

Sekian report dari Bandung yang lagi dingin-dinginnya nih ujan terus :) ...thx to all !

Share this post: | | | |

LINQ To XML With VB 9.0 (Modify XML Data Easily - Relax For a While ;) )

yulian — Mon, 24 Nov 2008 09:11:00 GMT

LINQ To XML menyediakan suatu cara baru untuk memodifikasi data yang disimpan didalam file xml. Hal tersebut dipermudah lagi dengan adanya fitur XML Literal di VB 9.0 dalam hal penambahan elemen atau atribut baru. LINQ membantu dalam hal filtering data xml yang akan di modifikasi. Pada artikel ini saya akan memberikan contoh bagaimana caranya menambahkan elemen dan atribut, menghapus elemen, edit elemen dan edit atribut value.

Misalkan saya mempunyai sebuah file xml dengan nama Book.xml dengan data seperti dibawah ini :

<?xml version="1.0" encoding="utf-8" ?>
<Books>
  <Book CatID="1">
    <Title>Programming Visual Basic 9.0</Title>
    <Publisher>Apress</Publisher>
  </Book>
  <Book CatID="2">
    <Title>SQL Server 2008 Administration</Title>
    <Publisher>MS Press</Publisher>
  </Book>
  <Book CatID="3">
    <Title>Windows Server 2008</Title>
    <Publisher>MS Press</Publisher>
  </Book>
</Books>

Bagaimana caranya kalau kita ingin menambahkan data baru? Ada beberapa cara yang dapat dilakukan :

Menambahkan Elemen Baru

1. Add method

Untuk menambahkan elemen baru pada baris yang terakhir anda bisa gunakan method Add. Pertama kita harus dapatkan terlebih dahulu object reference ke elemen Books. Gunakan method First untuk mendapatkannya. Method ini akan mengembalikan first elemen yang dicari.

Option Strict On

Module LinqToXML

    Sub Main()

        Dim xmlBook = XDocument.Load("../../Book.xml")

        xmlBook.<Books>.First.Add( _
            <Book CatID="1">
                <Title>Programming C# 3.0</Title>
                <Publisher>Sybex</Publisher>
            </Book>)

        'xmlBook.Save("../../Book.xml")
        Console.WriteLine(xmlBook)
        Console.ReadLine()

    End Sub

End Module

Kode diatas akan menghasilkan elemen baru Book dengan CatID=1 berikut Title dan Publisher seperti yang dapat dilihat pada xml literalnya. XML Literal merupakan fitur baru yang terdapat di VB 9.0 yang sangat memudahkan kita untuk melakukan modifikasi data di file xml. Dengan XML Literal kita cukup ketikkan file xml seperti halnya kita ketik string literal. Secara otomatis data type nya di infer sebagai XElement. Berikut screen shot gambarnya :

2. AddAfterSelf method

Metoda ini digunakan untuk menambahkan elemen baru tepat dibawah elemen yang kita inginkan. Misalkan saya ingin menambahkan elemen baru setelah data Book yang memiliki CatID = 1. Berikut kode nya :

Sub Main()

    Dim xmlBook = XDocument.Load("../../Book.xml")

    Dim xmlData = From elem In xmlBook...<Book> _
                  Where elem.@CatID.ToString.Equals("1") _
                  Select elem

    xmlData.First.AddAfterSelf( _
        <Book CatID="1">
            <Title>Programming C# 3.0</Title>
            <Publisher>Sybex</Publisher>
        </Book>)

    'xmlBook.Save("../../Book.xml")
    Console.WriteLine(xmlBook)
    Console.ReadLine()

End Sub

Kode diatas akan menambahkan elemen baru setelah elemen dengan atribut CatID = 1 :

3. AddBeforeSelf method

Metoda ini kebalikannya dengan metoda di atas. Misalkan saya ingin menambahkan elemen baru sebelum data Book dengan CatID = 1 yang mengandung title "Visual Basic" :

Sub Main()

    Dim xmlBook = XDocument.Load("../../Book.xml")

    Dim xmlData = From elem In xmlBook...<Book> _
                  Where elem.@CatID.ToString.Equals("1") _
                  AndAlso elem.<Title>.Value.Contains("Visual Basic") _
                  Select elem

    xmlData.First.AddBeforeSelf( _
        <Book CatID="1">
            <Title>Programming C# 3.0</Title>
            <Publisher>Sybex</Publisher>
        </Book>)

    'xmlBook.Save("../../Book.xml")
    Console.WriteLine(xmlBook)
    Console.ReadLine()

End Sub

hasilnya :

Mudah kan ;) ...dengan LINQ To XML dan XML Literal di VB 9.0 si programmer bisa happy kalau dapat tugas buat modifikasi file xml, yang sebelumnya cukup sedikit nightmare kalau dapat tugas ini di VB.NET versi sebelumnya :D

Sekarang muncul pertanyaan lainnya : Bagaimana caranya kalau kita ingin merubah value sebuah elemen atau atribut? Berikut caranya :

Merubah Nilai Elemen dan Atribut

1. SetElementValue

Method tersebut membutuhkan input parameter nama elemen dan value baru yang akan dirubah. Untuk merujuk pada elemen yang akan dirubah, anda bisa menggunakan fungsi First atau Single (tergantung kebutuhan aplikasi) :

    Sub Main()

        Dim xmlBook = XDocument.Load("../../Book.xml")

        Dim xmlData = From elem In xmlBook...<Book> _
                      Where elem.@CatID.ToString.Equals("1") _
                      AndAlso elem.<Title>.Value.Contains("Visual Basic") _
                      Select elem

        xmlData.First.SetElementValue("Title", "LINQ With VB 9.0")
        'atau
        'xmlData.Single.SetElementValue("Title", "LINQ With VB 9.0")


        'xmlBook.Save("../../Book.xml")
        Console.WriteLine(xmlBook)
        Console.ReadLine()

    End Sub

hasilnya :

2. SetValue

Method ini berbeda dengan method di atas. Untuk method ini kita harus tentukan terlebih dahulu elemen mana yang akan kita rubah nilainya :

xmlData...<Title>.First.SetValue("LINQ With VB 9.0")
'atau
'xmlData...<Title>.Single.SetValue("LINQ With VB 9.0")

Kode diatas hanya membutuhkan satu input parameter untuk merubah nilai dari elemen Title. Hasilnya sama seperti pada gambar di atas.

3. SetAtributeValue

Method ini digunakan untuk merubah nilai dari suatu atribut. Misalkan data dengan atribut CatID = 1 ini akan dirubah nilainya menjadi 4 :

Sub Main()

    Dim xmlBook = XDocument.Load("../../Book.xml")

    Dim xmlData = From elem In xmlBook...<Book> _
                  Where elem.@CatID.ToString.Equals("1") _
                  Select elem

    xmlData.First.SetAttributeValue("CatID", "4")
    'atau
    'xmlData.Single.SetAttributeValue("CatID", "4")


    'xmlBook.Save("../../Book.xml")
    Console.WriteLine(xmlBook)
    Console.ReadLine()

End Sub

hasilnya :

Menghapus Elemen

Menghapus elemen tertentu sesuai dengan kriteria yang diinginkan?? Mudah sekali caranya teman :D ...dengan menggunakan LINQ To XML dan Remove method, anda dapat melakukannya sambil minum kopi ;)

Sub Main()

    Dim xmlBook = XDocument.Load("../../Book.xml")

    Dim xmlData = From elem In xmlBook...<Book> _
                  Where elem.@CatID.ToString.Equals("3") _
                  Select elem

    xmlData.First.Remove()
    'atau
    'xmlData.Single.Remove()


    'xmlBook.Save("../../Book.xml")
    Console.WriteLine(xmlBook)
    Console.ReadLine()

End Sub

hasilnya :

Ok...sampai disini dulu teman ;) O ya...happy coding Vb-ers :D

Share this post: | | | |

LINQ To XML With VB 9.0 (Select and Join Multiple XML File)

yulian — Thu, 20 Nov 2008 07:47:00 GMT

LINQ To XML merupakan fitur baru yang terdapat di VB 9.0. Fitur ini digunakan untuk memudahkan melakukan query data yang disimpan di file XML. Sebelumnya hal tersebut dilakukan dengan menggunakan XMLReader, XPathDocument dengan XPath Query sebagai sarana untuk filtering data xml nya. Penggunaan class-class tersebut saya rasakan begitu "merepotkan" :) ...Beruntung lah dengan adanya fitur LINQ To XML ini.

Kali ini saya akan membahas bagaimana caranya melakukan query data xml dan Join data dari dua file xml. Query operator yang digunakan sama dengan hal nya query operator untuk LINQ terhadap object lain. Namun LINQ To XML ini ada sedikit perbedaan dalam hal pengaksesan elemen dan atributnya.

Misalkan saya memiliki file xml seperti dibawah ini (Book.xml) :

<?xml version="1.0" encoding="utf-8" ?>
<Books>
  <Book CatID="1">
    <Title>Programming Visual Basic 9.0</Title>
    <Publisher>Apress</Publisher>
  </Book>
  <Book CatID="1">
    <Title>Programming C# 3.0</Title>
    <Publisher>Adison Wesley</Publisher>
  </Book>
  <Book CatID="2">
    <Title>SQL Server 2008 Administration</Title>
    <Publisher>MS Press</Publisher>
  </Book>
  <Book CatID="2">
    <Title>MS Access 2007</Title>
    <Publisher>Que</Publisher>
  </Book>
  <Book CatID="3">
    <Title>Windows Vista Administration</Title>
    <Publisher>Sams</Publisher>
  </Book>
  <Book CatID="3">
    <Title>Windows Server 2008</Title>
    <Publisher>MS Press</Publisher>
  </Book>
</Books>

Dengan Linq To XML untuk melakukan query data di atas sangatlah mudah. Berikut kode untuk menampilkan data dari atribut CatID, elemen Title dan elemen Publisher :

Option Strict On

Module LinqToXML

    Sub Main()
        Dim xmlBook = XDocument.Load("../../Book.xml")

        Dim xmlData = From elem In xmlBook.Descendants("Book")

        For Each elem In xmlData
            Dim strID = CStr(elem.Attribute("CatID").Value)
            Dim strTitle = CStr(elem.Element("Title").Value)
            Dim strPub = CStr(elem.Element("Publisher").Value)

            Dim strBook = String.Format( _
            "CatID:{0,-2} Title:{1,-30} Publisher:{2}", _
                                        strID, strTitle, strPub)
            Console.WriteLine(strBook)
        Next
        Console.ReadLine()
    End Sub

End Module

Untuk load file xml gunakan XDocument class. XDocument class tersebut memiliki Shared Function Load yang membutuhkan input parameter berupa lokasi dari file xml yang akan digunakan.

Fungsi Descendants digunakan untuk mengakses semua elemen-elemen relatif terhadap root elemen. Pada contoh di atas saya ingin akses semua elemen Book. Untuk menampilkan detail data elemen dan atributnya kita lakukan looping terhadap semua koleksi XElement (xmlData).

Fungsi Attribute akan mengembalikan XAttribute type dan digunakan untuk akses atribute pada elemen dimana attribute tersebut berada, sedangkan fungsi Element akan mengembalikan XElement type dan digunakan untuk akses elemen.

Anda dapat melakukan konversi ke primitive data type terhadap value dari elemen dan atribut dengan fungsi yang telah disediakan di .net framework class library. Berikut screen shot hasil eksekusi kode diatas :

VB 9.0 memiliki fitur yang berbeda dengan C# 3.0 dalam hal akses elemen, atribut, dan descendant. Perbedaan tersebut terletak pada fitur axis property yang diberikan dengan simbol ...<> untuk akses Descendant, <> untuk akses element, dan @ untuk akses atribut. Berikut modifikasi kode diatas dengan menggunakan fitur axis properti :

Dim xmlData = From elem In xmlBook...<Book>

For Each elem In xmlData
    Dim strID = CStr(elem.@CatID)
    Dim strTitle = CStr(elem...<Title>.Value)
    Dim strPub = CStr(elem...<Publisher>.Value)

Dapat kita lihat dengan menggunakan axis properti maka penulisan descendant, elemen dan atribute lebih "Human Readable" :)

Lalu bagaimana caranya kalau kita ingin menampilkan data distinct terhadap sebuah elemen atau atribut? Misalkan saya ingin menampilkan data distinct untuk atribut CatID :

Sub Main()
    Dim xmlBook = XDocument.Load("../../Book.xml")

    Dim xmlData = From elem In xmlBook...<Book> _
                  Select elem.@CatID Distinct

    For Each elem In xmlData
        Dim strID = elem

        Dim strCatID = String.Format("CatID:{0,-2}", strID)
        Console.WriteLine(strID)
    Next
    Console.ReadLine()
End Sub

Filtering data berdasarkan nilai dari elemen atau atribut tertentu?

Dim xmlData = From elem In xmlBook...<Book> _
              Where CStr(elem.@CatID).Equals("1")

Kode diatas digunakan untuk filtering data xml dimana CatID bernilai "1". Cukup sederhana bukan bila kita bandingkan dengan cara XPath Query konvensional? :D

Kemudian sekarang ada pertanyaan lain...Bagaimana caranya kalau saya ingin melakukan join dari dua buah file xml? Misalkan kita memiliki satu file xml dengan nama Category.xml yang isinya sebagai berikut :

<?xml version="1.0" encoding="utf-8" ?>
<Categories>
  <Category ID="1">
    <Name>Programming</Name>
  </Category>
  <Category ID="2">
    <Name>Database</Name>
  </Category>
  <Category ID="3">
    <Name>Operating System</Name>
  </Category>
</Categories>

Saya ingin gabungkan file Book.xml dan file Category.xml yang akan menampilkan output berupa Nama Kategori dari Title buku yang ada beserta Title nya itu sendiri. Mari kita lihat kode dibawah ini :

Sub Main()
    Dim xmlBook = XDocument.Load("../../Book.xml")
    Dim xmlCategory = XDocument.Load("../../Category.xml")

    Dim xmlData = From book In xmlBook...<Book> _
                  Join cat In xmlCategory...<Category> _
                  On book.@CatID Equals cat.@ID _
                  Select cat.<Name>, book.<Title>

    For Each elem In xmlData
        Dim strCatName = CStr(elem.Name.Value)
        Dim strTitle = CStr(elem.Title.Value)

        Dim strBook = String.Format( _
        "Category:{0,-20} Title:{1,-30}", _
                                    strCatName, strTitle)
        Console.WriteLine(strBook)
    Next
    Console.ReadLine()
End Sub

Untuk Join dua file xml pertama anda harus load terlebih dahulu kedua file xml yang akan digunakan. Setelah itu untuk menggabungkan dua file xml yang telah diload tersebut gunakan perintah Join terhadap descendant elemen yang akan diakses diikuti dengan perintah On terhadap elemen yang digunakan sebagai link diantara kedua file xml. Perintah Equals harus digunakan untuk membandingkan nilai-nilai dari elemen atau atribut. Ya...mungkin perintah tersebut sangat familiar bila kita sering menggunakan perintah SQL dalam melakukan join :) ...Berikut screen shot hasil dari eksekusi kode diatas :

Happy coding Vb-ers :) ...pada artikel selanjutnya saya akan membahas bagaimana caranya melakukan modifikasi data file xml untuk operasi penambahan, hapus, dan edit terhadap elemen atau atribut.

Share this post: | | | |

Lambda Expression In VB 9.0 (Func and Function)

yulian — Wed, 19 Nov 2008 14:14:00 GMT

VB 9.0 syarat dengan fitur-fitur baru yang dapat "memanjakan" para programmer dalam menyelesaikan suatu kasus ataupun mempermudah penulisan code menjadi lebih simple. Kali ini saya akan membahas fitur Lambda Expression di VB 9.0. Func dan Function (Inline function) merupakan implementasi dari Lambda Expression.

Func merupakan sebuah delegate type. Jadi anda dapat membuat sebuah delegate tanpa harus mendeklarasikan terlebih dahulu delegate type nya. Func dibuat dengan menggunakan input parameter yang maksimum jumlahnya empat atau tanpa input parameter. Didalam Func ini didefinisikan juga tipe data return value nya.

Saya buat contoh sederhana terlebih dahulu penggunaan "Classic Delegate" :

Public Class LambdaExpressionVB9

    Private Delegate Function MyDelegateFunction(ByVal Input As Integer) As Boolean

    Private Function IsEvenFunction(ByVal Number As Integer) As Boolean
        Return Number Mod 2 = 0
    End Function

    Private Sub btnClassicDelegate_Click(ByVal sender As System.Object, _
                                         ByVal e As System.EventArgs) _
                                         Handles btnClassicDelegate.Click

        Dim execNumber As MyDelegateFunction = AddressOf IsEvenFunction
        Dim IsEven = execNumber(2)
        MsgBox(IsEven) '// hasilnya True

    End Sub

End Class

Sekarang bandingkan penggunaan delegate dengan Func :

Public Class LambdaExpressionVB9

    Private Function IsEvenFunction(ByVal Number As Integer) As Boolean
        Return Number Mod 2 = 0
    End Function

    Private Sub btnFunc_Click(ByVal sender As System.Object, _
                              ByVal e As System.EventArgs) _
                              Handles btnFunc.Click

        Dim execNumber As Func(Of Integer, Boolean) = _
                AddressOf IsEvenFunction

        Dim IsEven = execNumber(3)
        MsgBox(IsEven) '// hasilnya False

    End Sub

End Class

Kode diatas dibuat untuk mengecek apakah sebuah bilangan itu bilang genap atau ganjil. Func yang saya create membutuhkan satu buah input parameter dengan tipe data Integer (Of Integer), sedangkan return valuenya berupa Boolean. Dapat anda lihat diatas, dengan Func maka kita bisa menghilangkan deklarasi signature delegate seperti yang biasa kita lakukan.

Lalu apa itu Function (Inline Function) ??

Inline Function ialah sebuah fungsi tanpa nama. Tipe data return valuenya di infer dari block code yang ditulis. Dengan Inline function ini kita dapat deklarasikan sebuah fungsi seperti kita deklarasikan variabel biasa. Kode di atas akan saya rubah dengan menggunakan Inline Function untuk delegate nya :

Public Class LambdaExpressionVB9

    Private Sub btnInlineFunction_Click(ByVal sender As System.Object, _
                                        ByVal e As System.EventArgs) _
                                        Handles btnInlineFunction.Click

        Dim execNumber As Func(Of Integer, Boolean) = _
                        Function(Num As Integer) Num Mod 2 = 0

        Dim IsEven = execNumber(2)
        MsgBox(IsEven) '// hasilnya True

    End Sub

End Class

Signature Inline Function harus sesuai dengan signature delegate Func (Untuk kasus diatas harus ada satu buah input parameter integer). Sedangkan tipe data return valuenya di infer dari block code Inline Function itu sendiri (Dalam hal ini Num Mod 2 = 0)...So mana yang lebih efektif dari sisi teknik pengkodeannya? ;)

Happy Coding Vb-ers !! :)

Share this post: | | | |

Create Your Own Event and Event Handler With Your Own Delegate In VB.NET

yulian — Wed, 19 Nov 2008 13:14:00 GMT

Salah satu implementasi dari delegate ialah membuat event handler yang menangani event dengan signature yang telah ditentukan. Delegate merupakan sebuah type. Implementasi lain dari delegate ialah Callback mechanism. Namun pada artikel kali ini saya akan membahas implementasi delegate untuk event dan event handler.

Bayangkan anda mempunyai sebuah class. Di dalam class tersebut terdapat sebuah property dimana proses assignment valuenya harus divalidasi dengan sebuah rule tertentu, lalu anda ingin propagate notifikasi ke user jika validasinya tidak valid berupa message errornya. Ok...mari kita buat class yang sederhana :

Public Class Order

    Private mQty As Integer
    Public Property Quantity() As Integer
        Get
            Return mQty
        End Get
        Set(ByVal value As Integer)
            mQty = value
        End Set
    End Property

End Class

Misalkan aplikasi punya rule bahwa untuk memberikan nilai pada properti Quantity valuenya harus lebih besar nol, lalu notifikasi error message nya kita deliver ke user bila rule tersebut tidak dipenuhi. Bagaimana langkah2nya? Pertama buat terlebih dahulu delegate object nya :

Public Class Order

    Private Delegate Sub MyDelegateSub(ByVal Message As String)

Delegate yang saya buat signature nya berupa sebuah Sub yang memiliki satu buah input parameter dengan tipe data string. Langkah kedua buat event yang kita definisikan sendiri namanya dimana event handler yang akan dibuat nantinya harus sesuai dengan signature delegate diatas :

Public Class Order

    Private Delegate Sub MyDelegateSub(ByVal Message As String)
    Private Event MustBeGTZero As MyDelegateSub

Langkah berikutnya buat event handler nya. Ingat syarat diatas :

Public Class Order

    Private Delegate Sub MyDelegateSub(ByVal Message As String)
    Private Event MustBeGTZero As MyDelegateSub

    Private Sub MustBeGTZeroHandler(ByVal Notification As String)
        MsgBox(Notification)
    End Sub

Signature event handler sama dengan delegate (berupa Sub dengan satu buah input parameter yang bertipe data string, untuk nama input parameternya ga harus sama).

Next step is, lakukan proses validasi pada Setter property. Disini kita harus lakukan assignment event handler dengan event secara run time, raise event, setelah itu disassociate event handler dengan eventnya, berikut code lengkapnya :

Public Class Order

    Private Delegate Sub MyDelegateSub(ByVal Message As String)
    Private Event MustBeGTZero As MyDelegateSub

    Private Sub MustBeGTZeroHandler(ByVal Notification As String)
        MsgBox(Notification)
    End Sub

    Private mQty As Integer
    Public Property Quantity() As Integer
        Get
            Return mQty
        End Get
        Set(ByVal value As Integer)
            If value <= 0 Then
                AddHandler MustBeGTZero, AddressOf MustBeGTZeroHandler
                RaiseEvent MustBeGTZero("Input harus lebih besar dari Nol")
                RemoveHandler MustBeGTZero, AddressOf MustBeGTZeroHandler
            Else
                mQty = value
            End If
        End Set
    End Property

End Class

Untuk trigger event yang telah kita buat gunakan perintah RaiseEvent. Berikut contoh penggunaannya di aplikasi client :

Private Sub btnGetOrder_Click(ByVal sender As System.Object, _
                              ByVal e As System.EventArgs) _
                              Handles btnGetOrder.Click
    Dim myOrder = New Order With {.Quantity = -1}
End Sub

Kembali saya menggunakan VB 9.0. Kode diatas menggabungkan fitur Local Type Inference dengan Object Initialization Expression. Screen shot nya seperti dibawah ini :

Happy Coding VB-ers !! ;)

Share this post: | | | |

Create VB.NET Event Handler In Various Way

yulian — Wed, 19 Nov 2008 13:09:00 GMT

Untuk para programmer yang sebelumnya berkecimpung di dunia VB 6.0 mungkin salah satu hal yang wajib dipelajari yaitu mengenai Event dan Event Handler. Mungkin selama ini kita buat event handler dengan cara yang standard. Artinya kita cukup cari nama event yang akan digunakan untuk object yang bersangkutan lewat properties window atau Code Viewer di Visual Studio.

Berikut adalah event handler untuk event click kontrol Button :

Private Sub btnSave_Click(ByVal sender As System.Object, _
                              ByVal e As System.EventArgs) _
                              Handles btnSave.Click

End Sub

yang harus diperhatikan oleh VB 6 programmer yaitu keyword Handles. Keyword tersebut merupakan kunci assignment sebuah event handler dengan event nya. Anda bebas untuk mengubah nama event handler nya selama keyword Handles nya merujuk ke event dari object yang anda inginkan. Hal ini berbeda sekali dengan VB 6, bila anda ganti nama event handler nya maka prosedur tersebut tidak akan pernah di ekseskusi.

Misalkan saya memiliki tiga buah control Button dengan masing-masing event handler nya untuk event Click seperti dibawah ini :

Private Sub btnSave_Click(ByVal sender As System.Object, _
                          ByVal e As System.EventArgs) _
                          Handles btnSave.Click
    MsgBox("Save")
End Sub

Private Sub btnDelete_Click(ByVal sender As System.Object, _
                            ByVal e As System.EventArgs) _
                            Handles btnDelete.Click
    MsgBox("Delete")
End Sub

Private Sub btnCancel_Click(ByVal sender As System.Object, _
                            ByVal e As System.EventArgs) _
                            Handles btnCancel.Click
    MsgBox("Cancel")
End Sub

Bila business rule dari ketiga event handler tersebut mirip dan kontrol nya juga sama, apakah kode diatas cukup efektif? Mungkin kita bisa buat cara lain untuk menghemat space code designer :)) bagaimana caranya? Kita bisa buat satu buah event handler yang menangani lebih dari satu event untuk masing-masing kontrol. Intinya terdapat pada Handles keyword :

Private Sub ClickEventHandler(ByVal sender As Object, ByVal e As EventArgs) _
    Handles btnSave.Click, btnCancel.Click, btnDelete.Click

End Sub

Setelah Handles keyword anda tinggal definisikan event-event yang akan dibuatkan handler nya dari masing-masing kontrol dengan dipisahkan dengan tanda koma. Lalu sekarang bagaimana caranya kita mengetahui control mana yang mentrigger event tsb? Dengan variabel sender yang terdapat pada parameter pertama di prosedur tsb. Yang harus dilakukan adalah melakukan casting explicit ke kontrol yang mentrigger event tsb. Setelah didapatkan object nya maka kita dapat memanfaatkan properti yang dimiliki oleh kontrol tsb untuk identifikasi. Properti yang mudah dan umum digunakan yaitu properti Name. Berikut code nya :

Private Sub ClickEventHandler(ByVal sender As Object, ByVal e As EventArgs) _
    Handles btnSave.Click, btnCancel.Click, btnDelete.Click

    Dim aButton = DirectCast(sender, Button)
    Select Case aButton.Name.ToLower
        Case "btnsave"
            MsgBox("Save")
        Case "btncancel"
            MsgBox("Cancel")
        Case "btndelete"
            MsgBox("Delete")
    End Select
End Sub

Lebih menghemat space kan :D ? Kode ini saya buat dengan VB 9.0, jadi variabel aButton tersebut tipe datanya langsung di Infer oleh si CLR. Cara lainnya gimana nih? Apakah ada cara lain untuk assignment event handler terhadap sebuah event? Ada...cara ini berguna kalau anda ingin membuat event handler secara dinamis. Pertama anda buat terlebih dahulu event handler nya dengan signature yang sama tanpa keyword Handles :

Private Sub ClickEventHandler(ByVal sender As Object, ByVal e As EventArgs)
    Dim aButton = DirectCast(sender, Button)
    Select Case aButton.Name.ToLower
        Case "btnsave"
            MsgBox("Save")
        Case "btncancel"
            MsgBox("Cancel")
        Case "btndelete"
            MsgBox("Delete")
    End Select
End Sub

Setelah itu langkah yang harus dilakukan yaitu proses assignmentnya. Gunakan AddHandler keyword. Anda bisa tempatkan perintah tersebut dimana saja. Contoh berikut saya tempatkan di event Load dari form yang digunakan :

Private Sub EventAndEventHandler_Load(ByVal sender As System.Object, _
                                      ByVal e As System.EventArgs) _
                                      Handles MyBase.Load
    AddHandler btnSave.Click, AddressOf ClickEventHandler
    AddHandler btnCancel.Click, AddressOf ClickEventHandler
    AddHandler btnDelete.Click, AddressOf ClickEventHandler
End Sub

Perintah AddressOf merupakan sebuah object Delegate. Lalu ada seseorang bertanya pada saya...Pak disitu pake perintah AddHandler, berarti ada dong perintah lainnya yang berseberangan dengan perintah tsb?? Ada...RemoveHandler jawabannya :)

Perintah Remove Handler digunakan untuk "memutuskan" asosiasi antara event dengan event handler nya. Hal tersebut berguna agar tidak terjadi proses assignment event handler lebih dari satu kali. Penulisan kode nya sama, seperti berikut :

Private Sub btnRemoveHandler_Click(ByVal sender As System.Object, _
                                   ByVal e As System.EventArgs) _
                                   Handles btnRemoveHandler.Click
    RemoveHandler btnSave.Click, AddressOf ClickEventHandler
    RemoveHandler btnCancel.Click, AddressOf ClickEventHandler
    RemoveHandler btnDelete.Click, AddressOf ClickEventHandler
End Sub

Begitulah ceritanya ;) ... anda tinggal memlilih cara mana yang sesuai dengan kebutuhan aplikasi tersebut. C U on the next articles ;)

Share this post: | | | |

Weekend Day with MUGI Bandung + MS Indo Event Reporting

yulian — Mon, 10 Nov 2008 01:58:00 GMT

Hari sabtu minggu kemarin tepatnya pada tanggal 8 Nov 2008 di Unpas Setiabudi Bandung telah diadakan Kuliah umum dengan tema Weekend Day With MUGI Bandung dan MS Indo. Acara ini merupakan hasil kerja sama antara pihak MUGI + MUGI Bandung + MS Indo + Jurusan Informatika Unpas. Acara dimulai sekitar pukul 9.00 pagi WIB yang dibuka oleh ketua Dekan Unpas, ketua jurusan IF Unpas, ketua Himpunan IF Unpas. Rencana semula sebenarnya akan dibuka oleh Rektor Unpas, namun beliau tidak dapat hadir karena ada halangan.

Para peserta yang hadir tampak antusias sekali menyaksikan acara ini, dapat dilihat dari kehadiran mereka dari pagi sampai acara berakhir pada pukul setengah 5. Kami sangat berterima kasih sekali pada panitia yang telah membuat acara ini lebih dari yang kita bayangkan sebelumnya. Mereka telah membuat baligo ukuran besar, spanduk, flyer, stiker, menyediakan konsumsi makanan ringan plus teh botol dan aqua, sampai menyediakan makan siang prasmanan yang telah mereka sediakan...thanks!!! Mereka dengan sukarela mempersiapkan itu semua tanpa adanya "sumbangan" berupa dana dalam bentuk uang dari kita. Bahkan mereka memiliki budget sendiri untuk mempersiapkan itu semua dan para peserta ditarik uang tiket masuk sebesar Rp.15.000 atas inisiatif panitia itu sendiri. Jumlah peserta yang hadir mencapai 200 orang lebih. Itu pun mereka batasi dengan alasan kapasitas aula yang tidak cukup untuk menampung lebih dari 200 orang, dan sebenarnya banyak sekali para mahasiswa lainnya yang mereka tolak karena kapasitas...Wow...great job!! Thanks again to IF Unpas :)

Ketika Mugiers datang ke kampus Unpas sekitar pukul 8.00, kita telah disambut oleh ketua Dekan, ketua jurusan IF, dosen IF. Disana kita berbincang-bincang mengenai acara ini. Dan ketua dekan tersebut sangat mendukung sekali acara-acara seperti ini, dan beliau berharap acara ini dapat berlangsung kontinu dan mengharapkan kegiatan yang lebih dari sekedar kuliah umum, mungkin seperti workhsop...We will do!!

Pihak unpas sangat tertarik untuk bekerjasama dengan Mugi dan MS Indo, terutama dalam hal MSDNAA (Ini bagiannya mas Julius Fenata). Mas Julius dan mas Irsan sempat membicarakan hal tsb dengan ketua jurusan IF ketika istirahat makan siang di ruang Dekan (gimana mas hasilnya? :D ). Mugi Bandung akan berencana untuk membentuk Mugi Kampus. Unpas akan kita jadikan pilot project pertama dalam pembentukan Mugi kampus.

Tampak sekali para mahasiswa IF Unpas sangat jauh sekali dari "sentuhan" Microsoft technology. Mereka terbiasa dengan produk-produk open source dan produk non MS. Hal tersebut tidak ada salahnya. Namun kita memberikan perspektif dalam dunia nyata apabila mereka terjun nantinya ke dunia lapangan pekerjaan. Ya inilah target Mugi Bandung untuk "menjamah" kampus-kampus lainnya seperti Unpas ini...We will do again!!

Banyak sekali goodies yang kita sediakan pada mereka :)...ada buku, dvd developer kit, sql server 2008, visual studio 2008, windows vista ultimate, windows server 2008, kaos-kaos, video-video training...sampai-sampai bersisa dan kita bagikan dengan cara dilempar ke para peserta :)) sebagai ice breaker juga, hoalah...seru-seru! (ini idenya mas Irsan nih :D ). Mereka juga mendapatkan sertifikat yang dibagikan setelah acara selesai. Selain itu disana juga terdapat stand lowongan kerja dari Jatis.

Kami mengucapkan terima kasih pada pak Sony (Mugi Pusat) dan mugi jadetabek yang hadir, MS Indo yang telah mensupport kita. Dan satu lagi yaitu Bobby N.H yang telah menjadi fasilitator yang sukses :) antara pihak Unpas dengan Mugi Bandung...Memang cocok kamu jadi "Humas" Mugi Bandung bro! :)

What's next event? Kita berencana akan mengadakan acara serupa di STT Telkom pada bulan desember, semoga terlaksana :)

Berikut foto-foto kegiatannya. Anda juga dapat melihat foto-fotonya di Facebook Mugi Bandung Group :D...O ya saat itu juga ada kamerawan dari TVRI (pihak Unpas yang mengundangnya), dan pak Firstman (ketua Mugi Bandung) sempat diwawancara oleh mereka (wah masuk TV nih pak firstman :D )...

Pembacaan doa :

Audience :

Sambutan dari Ketua Dekan :

Sambutan dari Ketua Jurusan IF:

Sambutan dari Ketua Jurusan Himpunan IF:

Sambutan dari Ketua Panitia:

Firstman On "Introducing MUGI Bandung":

Irsan On "Microsoft Product Lincense":

Me On "Microsoft Certification":

Aris On "Microsoft Certification":

Fu On "Silverlight":

Narenda On "Virtualization":

Andri Yadi On "VSTO":

Ronald On "WPF":

Julius Fenata On "Microsoft Imagine Cup 2009":

Pertukaran Cindera mata antara MUGI Bandung dan Himpunan IF Unpas:

Setelah acara selesai, sekitar pukul 5 lebih kita masih diundang makan-makan oleh ketua jurusan IF dan dosen IF (Surabi nya enak + Singkong + Bajigur :D )...sayang mugiers yang lain sudah keburu pulang :D :

Bagi yang ingin melihat slide presentasi saya tentang sertifikasi Microsoft silahkan di download disini. Thx to All !!!

Share this post: | | | |

Weekend Day With MUGI - Knowledge Sharing About Microsoft Technology

yulian — Tue, 28 Oct 2008 10:31:00 GMT

Beberapa bulan terakhir ini MUGI Bandung disibukkan untuk mengaktifkan kembali kegiatan-kegiatan yang sifatnya Sharing Knowledge baik itu berupa Seminar, Kuliah Umum, maupun Workshop. Setelah melakukan briefing beberapa kali maka diputuskan event yang pertama kali akan kita buat yaitu Kuliah Umum di Unpas Bandung. Event ini akan dijadikan sebagai langkah awal untuk melanjutkan kegiatan-kegiatan selanjutnya.

MUGI Bandung berencana nantinya akan membuat agenda tahunan yang akan diadakan di kampus-kampus. Ibaratnya Road Show Campus To Campus :) Mungkin setelah event ini dalam waktu dekat ada beberapa kampus yang sudah masuk list MUGI Bandung untuk mengadakan kegiatan berikutnya. Jadi mari kita sukseskan event MUGI Bandung pertama ini sebagai langkah awal untuk dijadikan sebagai percontohan bagi kampus lainnya. Salut untuk mahasiswa Unpas yang begitu antusias dan bersemangat dalam mempersiapkan event ini !!!...So tunggu kita di hari H nya :D ...Terima kasih juga untuk semua anggota MUGI Bandung yang telah membantu dalam mempersiapkan event ini, terutama Bobby N.H "Humas" MUGI Bandung :) yang menjadi fasilitator dengan pihak Unpas, Pak Sony MUGI Pusat, begitu juga dukungan dari Microsoft Indonesia.

Berikut daftar acara yang akan dibawakan nanti :

Bagi mahasiswa Unpas (Universitas Pasundan) Bandung, please be there...O ya bagi peserta yang mendaftarkan diri nanti kita bakal bagi-bagi goodies yaitu DVD Developer Kit, Buku (beberapa), Kaos (beberapa), CD Office (beberapa) dan Sertifikat :)

Share this post: | | | |

Finally...MCT listed in my certification transcript as my newly certification :)

yulian — Sun, 28 Sep 2008 13:55:00 GMT

Akhirnya setelah beberapa tahun belakangan ini keinginan saya untuk mendapatkan sertifikasi MCT (Microsoft Certified Trainer) terkabul juga. Setelah saya mengisi MCT Enrollment lewat MCP Member Site dan sempat beberapa kali mengirim email ke searesc[at]microsoft.com karena dalam beberapa hari yang telah dijanjikan status MCT Applicationnya tidak juga Approved :))...sampai bosan juga bolak balik ke MCP member site hanya untuk melihat status Approved ;))...finallly MCT is listed as my newly certification as you can see in my certification transcript below :

Bagi yang belum mengetahui apa itu MCT akan saya jelaskan secara singkat.

MCT ialah sebuah sertifikasi dari Microsoft bagi orang yang berkecimpung di IT Training untuk produk-produk Microsoft. Syarat untuk menjadi MCT ialah harus sudah memiliki sertifikasi Microsoft sebelumnya, misalnya MCAD, MCSD, MCSE, MCPD, MCITP, dll. Untuk mendapatkan sertifikasi ini ada beberapa cara, seperti yang dapat anda lihat di situs ini http://www.microsoft.com/learning/mcp/mct/guide/

Lalu apa keuntungannya dengan mendapatkan sertifikasi MCT ini? Sudah pasti kita akan mendapatkan discount-discount untuk exam yang bisa mencapai 65%, discount buku-buku MS Press, link-link ke resources berguna yang telah disediakan Microsoft, MCT Summit, dll. Satu yang paling berguna bagi saya yaitu download Microsoft Official Curriculum (MOC). MOC ini merupakan kurikulum resmi dari Microsoft sebagai modul training yang diselenggarakan oleh CPLS. Artinya saya dapat menghemat untuk membeli buku-buku luar :)). Lalu apa itu CPLS (Certified Partner Learning Solution)?

CPLS merupakan lembaga training center yang sudah di sertifikasi oleh Microsoft untuk mengadakan training produk Microsoft dengan menggunakan MOC. Selain itu untuk deliver MOC ini CPLS harus mempekerjakan seorang MCT (harusnya :D ).

Seorang MCT juga sebenarnya harus deliver materi yang sesuai dengan track sertifikasi yang telah dia dapatkan. Seperti yang dapat anda lihat di potongan gambar transkrip saya dibawah ini :

Hal tersebut di atas dikarenakan track sertifikasi saya di application developer (MCP, MCAD, MCTS, MCPD). Lalu modul-modul MOC apa saja yang dapat saya deliver sesuai dengan ketentuan di atas? Ini dia list MOC yang dapat saya deliver (you have to own more enough internet quota for download, upgrade your Indosat 3.5G Broadband Unlimited to the higher package!! :)) you can't use Eco! Package ;)) ) :

Banyak sekali bukan :D...Anyway i would like to say thanks to "Mr.SS" and Mr.Andi (from Nettrain Rasuna Park Office) for their help. Without them i couldn't get this certification. Yang merasa ber inisial "SS" silahkan call me, i'll take you to "Ngopi Doeloe" cafe Bandung :))...halah inisial-inisial segala :D, ini aja liat blognya "Mr.SS" disini http://mugi.or.id/blogs/sony/ O ya, yang pasti logo certification saya bertambah ;))

Share this post: | | | |